Geforce File Manager

NAME	SIZE	ACTIONS
📄 array_size.cocci	1,696 B	[ EDIT ] \| [ DEL ]
📄 badty.cocci	1,722 B	[ EDIT ] \| [ DEL ]
📄 boolconv.cocci	1,472 B	[ EDIT ] \| [ DEL ]
📄 boolinit.cocci	2,249 B	[ EDIT ] \| [ DEL ]
📄 boolreturn.cocci	698 B	[ EDIT ] \| [ DEL ]
📄 bugon.cocci	1,482 B	[ EDIT ] \| [ DEL ]
📄 cond_no_effect.cocci	2,088 B	[ EDIT ] \| [ DEL ]
📄 cstptr.cocci	827 B	[ EDIT ] \| [ DEL ]
📄 doubleinit.cocci	1,391 B	[ EDIT ] \| [ DEL ]
📄 ifaddr.cocci	659 B	[ EDIT ] \| [ DEL ]
📄 ifcol.cocci	1,241 B	[ EDIT ] \| [ DEL ]
📄 irqf_oneshot.cocci	1,951 B	[ EDIT ] \| [ DEL ]
📄 newline_in_nl_msg.cocci	1,650 B	[ EDIT ] \| [ DEL ]
📄 noderef.cocci	1,194 B	[ EDIT ] \| [ DEL ]
📄 of_table.cocci	1,366 B	[ EDIT ] \| [ DEL ]
📄 orplus.cocci	1,028 B	[ EDIT ] \| [ DEL ]
📄 returnvar.cocci	1,253 B	[ EDIT ] \| [ DEL ]
📄 semicolon.cocci	1,062 B	[ EDIT ] \| [ DEL ]
📄 warn.cocci	1,661 B	[ EDIT ] \| [ DEL ]

[ CLOSE ]

EDIT: warn.cocci

/// Use WARN(1,...) rather than printk followed by WARN_ON(1)
///
// Confidence: High
// Copyright: (C) 2012 Julia Lawall, INRIA/LIP6.  GPLv2.
// Copyright: (C) 2012 Gilles Muller, INRIA/LiP6.  GPLv2.
// URL: http://coccinelle.lip6.fr/
// Comments:
// Options: --no-includes --include-headers

virtual patch
virtual context
virtual org
virtual report

@bad1@
position p;
@@

printk(...);
printk@p(...);
WARN_ON(1);

@r1 depends on context || report || org@
position p != bad1.p;
@@

printk@p(...);
*WARN_ON(1);

@script:python depends on org@
p << r1.p;
@@

cocci.print_main("printk + WARN_ON can be just WARN",p)

@script:python depends on report@
p << r1.p;
@@

msg = "SUGGESTION: printk + WARN_ON can be just WARN"
coccilib.report.print_report(p[0],msg)

@ok1 depends on patch@
expression list es;
position p != bad1.p;
@@

-printk@p(
+WARN(1,
  es);
-WARN_ON(1);

@depends on patch@
expression list ok1.es;
@@

if (...)
- {
  WARN(1,es);
- }

// --------------------------------------------------------------------

@bad2@
position p;
@@

printk(...);
printk@p(...);
WARN_ON_ONCE(1);

@r2 depends on context || report || org@
position p != bad1.p;
@@

printk@p(...);
*WARN_ON_ONCE(1);

@script:python depends on org@
p << r2.p;
@@

cocci.print_main("printk + WARN_ON_ONCE can be just WARN_ONCE",p)

@script:python depends on report@
p << r2.p;
@@

msg = "SUGGESTION: printk + WARN_ON_ONCE can be just WARN_ONCE"
coccilib.report.print_report(p[0],msg)

@ok2 depends on patch@
expression list es;
position p != bad2.p;
@@

-printk@p(
+WARN_ONCE(1,
  es);
-WARN_ON_ONCE(1);

@depends on patch@
expression list ok2.es;
@@

if (...)
- {
  WARN_ONCE(1,es);
- }