Geforce File Manager

NAME	SIZE	ACTIONS
📄 array_size.cocci	1,696 B	[ EDIT ] \| [ DEL ]
📄 badty.cocci	1,722 B	[ EDIT ] \| [ DEL ]
📄 boolconv.cocci	1,472 B	[ EDIT ] \| [ DEL ]
📄 boolinit.cocci	2,249 B	[ EDIT ] \| [ DEL ]
📄 boolreturn.cocci	698 B	[ EDIT ] \| [ DEL ]
📄 bugon.cocci	1,482 B	[ EDIT ] \| [ DEL ]
📄 cond_no_effect.cocci	2,088 B	[ EDIT ] \| [ DEL ]
📄 cstptr.cocci	827 B	[ EDIT ] \| [ DEL ]
📄 doubleinit.cocci	1,391 B	[ EDIT ] \| [ DEL ]
📄 ifaddr.cocci	659 B	[ EDIT ] \| [ DEL ]
📄 ifcol.cocci	1,241 B	[ EDIT ] \| [ DEL ]
📄 irqf_oneshot.cocci	1,951 B	[ EDIT ] \| [ DEL ]
📄 newline_in_nl_msg.cocci	1,650 B	[ EDIT ] \| [ DEL ]
📄 noderef.cocci	1,194 B	[ EDIT ] \| [ DEL ]
📄 of_table.cocci	1,366 B	[ EDIT ] \| [ DEL ]
📄 orplus.cocci	1,028 B	[ EDIT ] \| [ DEL ]
📄 returnvar.cocci	1,253 B	[ EDIT ] \| [ DEL ]
📄 semicolon.cocci	1,062 B	[ EDIT ] \| [ DEL ]
📄 warn.cocci	1,661 B	[ EDIT ] \| [ DEL ]

[ CLOSE ]

EDIT: orplus.cocci

/// Check for constants that are added but are used elsewhere as bitmasks
/// The results should be checked manually to ensure that the nonzero
/// bits in the two constants are actually disjoint.
///
// Confidence: Moderate
// Copyright: (C) 2013 Julia Lawall, INRIA/LIP6.  GPLv2.
// Copyright: (C) 2013 Gilles Muller, INRIA/LIP6.  GPLv2.
// URL: http://coccinelle.lip6.fr/
// Comments:
// Options: --no-includes --include-headers

virtual org
virtual report
virtual context

@r@
constant c,c1;
identifier i,i1;
position p;
@@

(
 c1 + c - 1
|
 c1@i1 +@p c@i
)

@s@
constant r.c, r.c1;
identifier i;
expression e;
@@

(
e | c@i
|
e & c@i
|
e |= c@i
|
e &= c@i
|
e | c1@i
|
e & c1@i
|
e |= c1@i
|
e &= c1@i
)

@depends on s@
position r.p;
constant c1,c2;
@@

* c1 +@p c2

@script:python depends on s && org@
p << r.p;
@@

cocci.print_main("sum of probable bitmasks, consider |",p)

@script:python depends on s && report@
p << r.p;
@@

msg = "WARNING: sum of probable bitmasks, consider |"
coccilib.report.print_report(p[0],msg)