Geforce File Manager

NAME	SIZE	ACTIONS
📄 bison-i18n.m4	1,924 B	[ EDIT ] \| [ DEL ]
📄 codeset.m4	842 B	[ EDIT ] \| [ DEL ]
📄 dovecot-pigeonhole.m4	1,895 B	[ EDIT ] \| [ DEL ]
📄 extern-inline.m4	4,368 B	[ EDIT ] \| [ DEL ]
📄 fcntl-o.m4	4,668 B	[ EDIT ] \| [ DEL ]
📄 fontutil.m4	14,160 B	[ EDIT ] \| [ DEL ]
📄 freetype2.m4	6,333 B	[ EDIT ] \| [ DEL ]
📄 gettext.m4	15,859 B	[ EDIT ] \| [ DEL ]
📄 glibc2.m4	830 B	[ EDIT ] \| [ DEL ]
📄 glibc21.m4	907 B	[ EDIT ] \| [ DEL ]
📄 gpg-error.m4	4,757 B	[ EDIT ] \| [ DEL ]
📄 gpgrt.m4	4,717 B	[ EDIT ] \| [ DEL ]
📄 iconv.m4	9,274 B	[ EDIT ] \| [ DEL ]
📄 intdiv0.m4	2,411 B	[ EDIT ] \| [ DEL ]
📄 intl.m4	12,120 B	[ EDIT ] \| [ DEL ]
📄 intldir.m4	917 B	[ EDIT ] \| [ DEL ]
📄 intlmacosx.m4	2,533 B	[ EDIT ] \| [ DEL ]
📄 intmax.m4	1,123 B	[ EDIT ] \| [ DEL ]
📄 inttypes-pri.m4	1,253 B	[ EDIT ] \| [ DEL ]
📄 inttypes_h.m4	1,020 B	[ EDIT ] \| [ DEL ]
📄 lcmessage.m4	1,365 B	[ EDIT ] \| [ DEL ]
📄 lib-ld.m4	3,683 B	[ EDIT ] \| [ DEL ]
📄 lib-link.m4	33,059 B	[ EDIT ] \| [ DEL ]
📄 lib-prefix.m4	8,466 B	[ EDIT ] \| [ DEL ]
📄 libgcrypt.m4	6,237 B	[ EDIT ] \| [ DEL ]
📄 libtool.m4	305,862 B	[ EDIT ] \| [ DEL ]
📄 libxml.m4	7,881 B	[ EDIT ] \| [ DEL ]
📄 libxslt.m4	8,119 B	[ EDIT ] \| [ DEL ]
📄 lock.m4	1,463 B	[ EDIT ] \| [ DEL ]
📄 longlong.m4	4,739 B	[ EDIT ] \| [ DEL ]
📄 ltargz.m4	2,569 B	[ EDIT ] \| [ DEL ]
📄 ltdl.m4	30,030 B	[ EDIT ] \| [ DEL ]
📄 ltoptions.m4	14,514 B	[ EDIT ] \| [ DEL ]
📄 ltsugar.m4	4,384 B	[ EDIT ] \| [ DEL ]
📄 ltversion.m4	699 B	[ EDIT ] \| [ DEL ]
📄 lt~obsolete.m4	6,140 B	[ EDIT ] \| [ DEL ]
📄 mysql.m4	4,221 B	[ EDIT ] \| [ DEL ]
📄 nls.m4	1,223 B	[ EDIT ] \| [ DEL ]
📄 pkg.m4	12,670 B	[ EDIT ] \| [ DEL ]
📄 po.m4	18,969 B	[ EDIT ] \| [ DEL ]
📄 printf-posix.m4	1,579 B	[ EDIT ] \| [ DEL ]
📄 progtest.m4	3,092 B	[ EDIT ] \| [ DEL ]
📄 size_max.m4	3,064 B	[ EDIT ] \| [ DEL ]
📄 stdint_h.m4	995 B	[ EDIT ] \| [ DEL ]
📄 threadlib.m4	15,151 B	[ EDIT ] \| [ DEL ]
📄 uintmax_t.m4	1,113 B	[ EDIT ] \| [ DEL ]
📄 visibility.m4	3,351 B	[ EDIT ] \| [ DEL ]
📄 wchar_t.m4	818 B	[ EDIT ] \| [ DEL ]
📄 wint_t.m4	1,053 B	[ EDIT ] \| [ DEL ]
📄 xsize.m4	406 B	[ EDIT ] \| [ DEL ]

[ CLOSE ]

EDIT: longlong.m4

# longlong.m4 serial 17
dnl Copyright (C) 1999-2007, 2009-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Paul Eggert.

# Define HAVE_LONG_LONG_INT if 'long long int' works.
# This fixes a bug in Autoconf 2.61, and can be faster
# than what's in Autoconf 2.62 through 2.68.

# Note: If the type 'long long int' exists but is only 32 bits large
# (as on some very old compilers), HAVE_LONG_LONG_INT will not be
# defined. In this case you can treat 'long long int' like 'long int'.

AC_DEFUN([AC_TYPE_LONG_LONG_INT],
[
  AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  AC_CACHE_CHECK([for long long int], [ac_cv_type_long_long_int],
     [ac_cv_type_long_long_int=yes
      if test "x${ac_cv_prog_cc_c99-no}" = xno; then
        ac_cv_type_long_long_int=$ac_cv_type_unsigned_long_long_int
        if test $ac_cv_type_long_long_int = yes; then
          dnl Catch a bug in Tandem NonStop Kernel (OSS) cc -O circa 2004.
          dnl If cross compiling, assume the bug is not important, since
          dnl nobody cross compiles for this platform as far as we know.
          AC_RUN_IFELSE(
            [AC_LANG_PROGRAM(
               [[@%:@include <limits.h>
                 @%:@ifndef LLONG_MAX
                 @%:@ define HALF \
                          (1LL << (sizeof (long long int) * CHAR_BIT - 2))
                 @%:@ define LLONG_MAX (HALF - 1 + HALF)
                 @%:@endif]],
               [[long long int n = 1;
                 int i;
                 for (i = 0; ; i++)
                   {
                     long long int m = n << i;
                     if (m >> i != n)
                       return 1;
                     if (LLONG_MAX / 2 < m)
                       break;
                   }
                 return 0;]])],
            [],
            [ac_cv_type_long_long_int=no],
            [:])
        fi
      fi])
  if test $ac_cv_type_long_long_int = yes; then
    AC_DEFINE([HAVE_LONG_LONG_INT], [1],
      [Define to 1 if the system has the type 'long long int'.])
  fi
])

# Define HAVE_UNSIGNED_LONG_LONG_INT if 'unsigned long long int' works.
# This fixes a bug in Autoconf 2.61, and can be faster
# than what's in Autoconf 2.62 through 2.68.

# Note: If the type 'unsigned long long int' exists but is only 32 bits
# large (as on some very old compilers), AC_TYPE_UNSIGNED_LONG_LONG_INT
# will not be defined. In this case you can treat 'unsigned long long int'
# like 'unsigned long int'.

AC_DEFUN([AC_TYPE_UNSIGNED_LONG_LONG_INT],
[
  AC_CACHE_CHECK([for unsigned long long int],
    [ac_cv_type_unsigned_long_long_int],
    [ac_cv_type_unsigned_long_long_int=yes
     if test "x${ac_cv_prog_cc_c99-no}" = xno; then
       AC_LINK_IFELSE(
         [_AC_TYPE_LONG_LONG_SNIPPET],
         [],
         [ac_cv_type_unsigned_long_long_int=no])
     fi])
  if test $ac_cv_type_unsigned_long_long_int = yes; then
    AC_DEFINE([HAVE_UNSIGNED_LONG_LONG_INT], [1],
      [Define to 1 if the system has the type 'unsigned long long int'.])
  fi
])

# Expands to a C program that can be used to test for simultaneous support
# of 'long long' and 'unsigned long long'. We don't want to say that
# 'long long' is available if 'unsigned long long' is not, or vice versa,
# because too many programs rely on the symmetry between signed and unsigned
# integer types (excluding 'bool').
AC_DEFUN([_AC_TYPE_LONG_LONG_SNIPPET],
[
  AC_LANG_PROGRAM(
    [[/* For now, do not test the preprocessor; as of 2007 there are too many
         implementations with broken preprocessors.  Perhaps this can
         be revisited in 2012.  In the meantime, code should not expect
         #if to work with literals wider than 32 bits.  */
      /* Test literals.  */
      long long int ll = 9223372036854775807ll;
      long long int nll = -9223372036854775807LL;
      unsigned long long int ull = 18446744073709551615ULL;
      /* Test constant expressions.   */
      typedef int a[((-9223372036854775807LL < 0 && 0 < 9223372036854775807ll)
                     ? 1 : -1)];
      typedef int b[(18446744073709551615ULL <= (unsigned long long int) -1
                     ? 1 : -1)];
      int i = 63;]],
    [[/* Test availability of runtime routines for shift and division.  */
      long long int llmax = 9223372036854775807ll;
      unsigned long long int ullmax = 18446744073709551615ull;
      return ((ll << 63) | (ll >> 63) | (ll < i) | (ll > i)
              | (llmax / ll) | (llmax % ll)
              | (ull << 63) | (ull >> 63) | (ull << i) | (ull >> i)
              | (ullmax / ull) | (ullmax % ull));]])
])