Geforce File Manager

NAME	SIZE	ACTIONS
📁 alloc		[ DEL ]
📁 debugfs		[ DEL ]
📄 check_bq27xxx_data.cocci	3,504 B	[ EDIT ] \| [ DEL ]
📄 d_find_alias.cocci	1,309 B	[ EDIT ] \| [ DEL ]
📄 drm-get-put.cocci	1,532 B	[ EDIT ] \| [ DEL ]
📄 err_cast.cocci	1,097 B	[ EDIT ] \| [ DEL ]
📄 kstrdup.cocci	2,461 B	[ EDIT ] \| [ DEL ]
📄 memdup.cocci	1,350 B	[ EDIT ] \| [ DEL ]
📄 memdup_user.cocci	1,306 B	[ EDIT ] \| [ DEL ]
📄 platform_no_drv_owner.cocci	3,869 B	[ EDIT ] \| [ DEL ]
📄 pm_runtime.cocci	2,394 B	[ EDIT ] \| [ DEL ]
📄 ptr_ret.cocci	1,814 B	[ EDIT ] \| [ DEL ]
📄 resource_size.cocci	2,115 B	[ EDIT ] \| [ DEL ]
📄 simple_open.cocci	1,244 B	[ EDIT ] \| [ DEL ]
📄 vma_pages.cocci	1,519 B	[ EDIT ] \| [ DEL ]

[ CLOSE ]

EDIT: d_find_alias.cocci

// SPDX-License-Identifier: GPL-2.0
/// Make sure calls to d_find_alias() have a corresponding call to dput().
//
// Keywords: d_find_alias, dput
//
// Confidence: Moderate
// URL: http://coccinelle.lip6.fr/
// Options: --include-headers

virtual context
virtual org
virtual patch
virtual report

@r exists@
local idexpression struct dentry *dent;
expression E, E1;
statement S1, S2;
position p1, p2;
@@
(
	if (!(dent@p1 = d_find_alias(...))) S1
|
	dent@p1 = d_find_alias(...)
)

<...when != dput(dent)
    when != if (...) { <+... dput(dent) ...+> }
    when != true !dent || ...
    when != dent = E
    when != E = dent
if (!dent || ...) S2
...>
(
	return <+...dent...+>;
|
	return @p2 ...;
|
	dent@p2 = E1;
|
	E1 = dent;
)

@depends on context@
local idexpression struct dentry *r.dent;
position r.p1,r.p2;
@@
* dent@p1 = ...
  ...
(
* return@p2 ...;
|
* dent@p2
)

@script:python depends on org@
p1 << r.p1;
p2 << r.p2;
@@
cocci.print_main("Missing call to dput()",p1)
cocci.print_secs("",p2)

@depends on patch@
local idexpression struct dentry *r.dent;
position r.p2;
@@
(
+ dput(dent);
  return @p2 ...;
|
+ dput(dent);
  dent@p2 = ...;
)

@script:python depends on report@
p1 << r.p1;
p2 << r.p2;
@@
msg = "Missing call to dput() at line %s."
coccilib.report.print_report(p1[0], msg % (p2[0].line))